REM  Hitachi SVP                              
REM  JAVA Update tool for Hitachi SVP
REM                 Copy right. 2018  Hitachi. Ltd. 
REM
REM History  :Version    :DATE        : Coder        : Patch No
REM Hitachi SVP
REM          :01-01      :2015.05.21  : S.Moriya  : Y8012222998 (New)
REM          :01-02      :2015.06.19  : S.Moriya  : Y8012223018
REM          :01-03      :2016.04.01  : H.Yasukawa: Y8792223590
REM          :01-04      :2018.03.29  : H.Satou   : 43501
REM

echo off

rem CredentialProvider enabel batch file

rem Windows 10 version check
set WIN_10=no
for /f "tokens=2 delims=[]" %%i in ('ver') do (
	set WINDOWS_VER=%%i
)
for /f "tokens=2,3 delims=. " %%i in ('echo %WINDOWS_VER%') do (
	set WINDOWS_MAJOR_VER=%%i& set WINDOWS_MINOR_VER=%%j
)

rem if "%WINDOWS_MAJOR_VER%"=="10" (
rem 	if "%WINDOWS_MINOR_VER%"=="0" (
rem 		set WIN_10=yes
rem 	)
rem )
if %WINDOWS_MAJOR_VER% geq 10 (
	set WIN_10=yes
)

rem UnRegister-GenericProvider.reg
reg delete "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Authentication\Credential Providers\{25CBB996-92ED-457e-B28C-4774084BD562}" /f

rem UnRegister-NPProvider.reg
reg delete "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Authentication\Credential Providers\{3dd6bec0-8193-4ffe-ae25-e08e39ea4063}" /f

rem UnRegister-PasswordProvider.reg
if "%WIN_10%" equ "yes" (
	reg delete "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Authentication\Credential Providers\{60b78e88-ead8-445c-9cfd-0b87f74ea6cd}" /f
) else (
	reg delete "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Authentication\Credential Providers\{6f45dc1e-5384-457a-bc13-2cd81b0d28ed}" /f
)

rem Register-CP.reg
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Authentication\Credential Providers\{b84ca702-35a8-4e67-8d2a-6c2906b396d4}" /t REG_SZ /d "SvpCred" /f
reg add "HKEY_CLASSES_ROOT\CLSID\{b84ca702-35a8-4e67-8d2a-6c2906b396d4}" /t REG_SZ /d "SvpCred" /f
reg add "HKEY_CLASSES_ROOT\CLSID\{b84ca702-35a8-4e67-8d2a-6c2906b396d4}\InprocServer32" /t REG_SZ /d "SvpCred.dll" /f
reg add "HKEY_CLASSES_ROOT\CLSID\{b84ca702-35a8-4e67-8d2a-6c2906b396d4}\InprocServer32" /v "ThreadingModel" /t REG_SZ /d "Apartment" /f


REM Administrator's usernmae check & disable Y8792223590
set EXIST_ADMINISTRATOR=no
set EXIST_XADMINISTRATOR=no

for /f "tokens=1" %%i in ('wmic useraccount get name') do (
	if /i "%%~i"=="Administrator" set EXIST_ADMINISTRATOR=yes
	if /i "%%~i"=="xadministrator" set EXIST_XADMINISTRATOR=yes
)

if "%EXIST_ADMINISTRATOR%" equ "yes" (
	REM administrator active:no
	net user administrator /active:no
	net user administrator
)

if "%EXIST_XADMINISTRATOR%" equ "yes" (
	REM xadministrator active:no
	net user xadministrator /active:no
	net user xadministrator
)


REM raid-admin active:yes
net user raid-admin /active:yes
net user raid-admin


exit /b 0