REM  Hitachi SVP                              
REM  JAVA Update tool for Hitachi SVP
REM                 Copy right. 2015  Hitachi. Ltd. 
REM
REM History  :Version    :DATE        : Coder        : Patch No
REM Hitachi SVP
REM          :01-01      :2015.05.21  : S.Moriya  : Y8012222998 (New)
REM          :01-02      :2018.02.16  : Y.Kumagai : #44854 (Remote Micro Exchange Support)
REM          :01-03      :2018.11.15  : M.Sugiyama : #62818 (Tomcat停止処理のリトライ対応)
REM
echo off
set REGCRED2="..\setup\RegCred.bat"
set LOGFILE="c:\dkc200\san\cgi-bin\Utility\JavaUpdate_log.txt"
SET CNT=0

:TOMCAT_STOP_WAIT

sc stop tomcat7 >> %LOGFILE% 2>>&1

timeout /T 60 >> %LOGFILE% 2>>&1

 SET TOMCAT_STOP_FLG=0
  for /f "tokens=1" %%i in ('tasklist /fi "IMAGENAME eq Tomcat7.exe"') do (
    IF "%%i"=="Tomcat7.exe" (
      SET TOMCAT_STOP_FLG=1
    )
  )
  
  SET /A CNT=CNT+1
  IF %TOMCAT_STOP_FLG%==1 (
  	IF %CNT% GTR 3 (
  	pushd %~dp0
	call %REGCRED2%  >> %LOGFILE% 2>>&1
  	echo Tomcat can not stop >> %LOGFILE% 2>>&1
  	echo Tomcat can not stop
	exit 243
  )
    echo [sleep Count=%CNT%.] >> %LOGFILE%
    goto :TOMCAT_STOP_WAIT
  )
 
exit /b 0