@echo off
set ARCH=
if %PROCESSOR_ARCHITECTURE%==x86 set ARCH=i386
if %PROCESSOR_ARCHITECTURE%==MIPS set ARCH=mips
if %PROCESSOR_ARCHITECTURE%==ALPHA set ARCH=alpha
if %PROCESSOR_ARCHITECTURE%==PPC set ARCH=PPC
echo Installing Client-based Network Administration Tools...
copy %ARCH%\*.exe %systemroot%\system32\*.* > nul:
if errorlevel 1 goto Error_COPY
copy %ARCH%\*.dll %systemroot%\system32\*.* > nul:
if errorlevel 1 goto Error_COPY
copy %ARCH%\*.hlp %systemroot%\system32\*.* > nul:
if errorlevel 1 goto Error_COPY
copy %ARCH%\*.cnt %systemroot%\system32\*.* > nul:
if errorlevel 1 goto Error_COPY
copy %ARCH%\*.adm %systemroot%\inf\*.* > nul:
if errorlevel 1 goto Error_COPY
copy %ARCH%\sfmmgr.dll %systemroot%\system32\sfmmgr.dll > nul:
if errorlevel 1 goto Error_COPY
if exist %systemroot%\system32\sfmreg.exe goto Sfm_REG
goto Exit_SUCCESS
:Sfm_REG
call %systemroot%\system32\sfmreg SMAddons sfmmgr.dll ntnet.ini > nul:
call %systemroot%\system32\sfmreg Addons sfmmgr.dll winfile.ini > nul:
goto Exit_SUCCESS
:Error_COPY
echo ÿ
echo The Client-based Network Administration Tools were not correctly
echo installed on the system. Check for sufficient disk space and correct
echo access permissions on the Windows NT system drive, then retry the
echo installation.  Setup must be run from the directory where the
echo Administration Tools reside.
echo ÿ
goto Exit_point
:Exit_SUCCESS
echo ÿ
echo The Client-based Network Administration Tools have been correctly installed.
echo You can create Program Manager icons for the following tools:
REM filter out sfmreg.exe, because it is only used for adding the
REM SFM addons to File Manager and Server Manager and is not an admin tool.
dir /b /l %ARCH%\*.exe | findstr /v sfmreg.exe
echo ÿ
goto Exit_point
:Exit_point
set ARCH=
pause