|
| Run file for Fireworkz 2.32.02 (12 Dec 2022)
|
Set Fireworkz$Dir <Obey$Dir>
|
Set Fireworkz$Help <Fireworkz$Dir>.!Help
Set Fireworkz$Version 2.32.02
Set Fireworkz$Web https://croftnuisk.co.uk/coltsoft/fireworkz/
Set Fireworkz$Title Fireworkz
Set Fireworkz$Description Integrated spreadsheet and word processor
Set Fireworkz$Publisher Colton Software
|
Set File$Type_BDF Firewrkz
Set Alias$@RunType_BDF Run <Fireworkz$Dir>.!Run %%*0
Set Alias$@PrintType_BDF Run <Fireworkz$Dir>.!Run -Print %%*0
|
Set File$Type_A78 FzDraw
| Embedded (OLE) files may be inserted as pictures in Fireworkz documents.
| They may be loaded as documents by Fireworkz by dragging them to the Fireworkz icon on the icon bar.
| However, to update or save them in their original form, you need to use Fireworkz Pro.
|
Set File$Type_C1D FwrkzTem
Set Alias$@RunType_C1D Run <Fireworkz$Dir>.!Run -Template %%*0
Set Alias$@PrintType_C1D Run <Fireworkz$Dir>.!Run -oPrint %%*0
|
Set File$Type_C1E FwrkzCmd
Set Alias$@RunType_C1E Run <Fireworkz$Dir>.!Run -Command %%*0
|
Set File$Type_C1C Wordz
Set Alias$@RunType_C1C Run <Fireworkz$Dir>.!Run %%*0
Set Alias$@PrintType_C1C Run <Fireworkz$Dir>.!Run -Print %%*0
|
Set File$Type_BE1 Resultz
Set Alias$@RunType_BE1 Run <Fireworkz$Dir>.!Run %%*0
Set Alias$@PrintType_BE1 Run <Fireworkz$Dir>.!Run -Print %%*0
|
Set File$Type_BE0 Recordz
| Recordz files are unlikely to be fully loaded by Fireworkz.
| To update or save them, you need to use Fireworkz Pro.
|
| Avoid overriding any other definition of file types we do not actually own
If "<File$Type_BA6>"="" Then Set File$Type_BA6 ExcelXLS
If "<Alias$@RunType_BA6>"="" Then Set Alias$@RunType_BA6 Run <Fireworkz$Dir>.!Run -import %%*0
|
If "<File$Type_C27>"="" Then Set File$Type_C27 Database
|
If "<File$Type_C32>"="" Then Set File$Type_C32 RTF
If "<Alias$@RunType_C32>"="" Then Set Alias$@RunType_C32 Run <Fireworkz$Dir>.!Run -import %%*0
|
If "<File$Type_DB0>"="" Then Set File$Type_DB0 LotusWK1
If "<Alias$@RunType_DB0>"="" Then Set Alias$@RunType_DB0 Run <Fireworkz$Dir>.!Run -import %%*0
|
If "<File$Type_DFE>"="" Then Set File$Type_DFE CSV
If "<Alias$@RunType_DFE>"="" Then Set Alias$@RunType_DFE Run <Fireworkz$Dir>.!Run -import %%*0
|
If "<File$Type_F0D>"="" Then Set File$Type_F0D TSV
If "<Alias$@RunType_F0D>"="" Then Set Alias$@RunType_F0D Run <Fireworkz$Dir>.!Run -import %%*0
|
RMEnsure UtilityModule 3.10 Error 0 Fireworkz needs RISC OS 3.10 or later
|
If "<Boot$OSVersion>"="" Then Error 0 Fireworkz needs Boot$OSVersion to be set
|
If (Boot$OSVersion>=500 AND Boot$OSVersion<600) Then IconSprites <Fireworkz$Dir>.!SpritesR5 Else IconSprites <Fireworkz$Dir>.!Sprites
|
RMEnsure UtilityModule 3.70 RMEnsure CallASWI 0.02 RMLoad System:Modules.CallASWI
RMEnsure UtilityModule 3.70 RMEnsure CallASWI 0.02 Error 0 SharedCLibrary needs CallASWI 0.02 or later. An updated 32-bit !System may be obtained from the RISC OS Open website
|
| Ensure we have the shared C library and determine its vintage
| NB Don't load a newer version over an older one that may be in RAM
|
Set Fireworkz$CLibLoaded 1
RMEnsure SharedCLibrary 0.00 Set Fireworkz$CLibLoaded 0
If Fireworkz$CLibLoaded=1 Then RMEnsure SharedCLibrary 5.45 Error 0 Fireworkz needs SharedCLibrary 5.45 or later but an earlier version is already running. An updated 32-bit !System may be obtained from the RISC OS Open website
Unset Fireworkz$CLibLoaded
|
RMEnsure SharedCLibrary 5.45 RMLoad System:Modules.CLib
RMEnsure SharedCLibrary 5.45 Error 0 Fireworkz needs SharedCLibrary 5.45 or later. An updated 32-bit !System may be obtained from the RISC OS Open website
|
RMEnsure ColourTrans 0.52 RMLoad System:Modules.Colours
RMEnsure ColourTrans 0.52 Error 0 Fireworkz needs ColourTrans 0.52 or later. An updated 32-bit !System may be obtained from the RISC OS Open website
|
| If you have no need to render Fireworkz Charts or other Drawfiles you can comment these out for pre-RISC OS 3.6 systems
RMEnsure Drawfile 1.30 RMLoad System:Modules.Drawfile
RMEnsure Drawfile 1.30 Error 0 Fireworkz needs Drawfile 1.30 or later. An updated 32-bit !System may be obtained from the RISC OS Open website
|
RMEnsure FPEmulator 4.10 RMLoad System:Modules.FPEmulator
RMEnsure FPEmulator 4.10 Error 0 Fireworkz needs FPEmulator 4.10 or later. An updated 32-bit !System may be obtained from the RISC OS Open website
|
RMEnsure BASIC 0.00 Error 0 Fireworkz's Loader needs BASIC. Is it unplugged?
|
If "<Choices$Write>"="" Then Error 0 Fireworkz needs Choices$Write to be set
|
| Ensure that the Choices directory is populated with some initial data
IfThere <Choices$Write>.Fireworkz.Choices.ChoicesDoc Then Else Obey <Fireworkz$Dir>.uChoices.DoCopy
|
WimpSlot -min 32K -max 32K
Run <Fireworkz$Dir>.Resources.Neutral.RISC_OS.Loader -id Fireworkz -ver 2.32.02 -isodate 20221212
|
| Fireworkz$Path is set appropriately by the Loader
| It is used to locate vital resources needed to run Fireworkz e.g. messages and sprite files
| and to locate most data presented to the Fireworkz user e.g. document templates, dictionaries, chart markers
| Fireworkz$TemplatesPath is also set appropriately by the Loader - it does not contain fallback locations
|
| If a Fireworkz$UserPath has been set, prepend Fireworkz$Path with that
If "<Fireworkz$UserPath>"<>"" Then Set Fireworkz$Path <Fireworkz$UserPath>,<Fireworkz$Path>
If "<Fireworkz$UserPath>"<>"" Then Set Fireworkz$TemplatesPath <Fireworkz$UserPath>.Templates.,<Fireworkz$TemplatesPath>
|
| On systems with only a small WimpSlot for application & its data, allow dynamic area to be used (limit in MB) 
If (Boot$OSVersion<500) OR (Boot$OSVersion>=600) Then Set Fireworkz$RunOptions <Fireworkz$RunOptions> --dynamic-area-limit=256
|
| The higher value is specified as the minimum first so that there is sufficient memory to get Fireworkz fully running
WimpSlot -min 1532K
| The lower value is specified as the maximum last so that becomes the initial slot that Fireworkz is started with
WimpSlot -max 1324K
| Equivalent to Run Fireworkz:RISC_OS.ImageSlot <Fireworkz$Dir>.!RunImage 10K 208K
|
Run <Fireworkz$Dir>.!RunImage %*0