$Id: bsc_help1.txt,v 1.1.1.2 1992/05/12 22:09:57 carr Exp $
PV-WAVE BASIC FUNCTIONS DEMONSTRATION

-----------------------------------------------------------------
SECTION 1.   (1-D DATA DISPLAY)
-----------------------------------------------------------------
In this section of the demo, an "ASCII Formatted" data
file containing four columns of numbers is used.
The contents of this file is as follows :

   SECONDS TEST1 TEST2 CODE
   10
   0000.33     2 -00.3 AAAD
    001.12    11-000.9AAABC
      2.27    09  05.5 BBDB
     13.650    7  37.4   CF
    015.97  0010 166.78DADB
     36.60    19 202.0    E
     55.67    34 218.5   EA
     60.01    32 219.9  EBB
     63.22    29 220.3  EC
     64.00    21 220.4  EDF

The PV-WAVE code to read this data file into PV-WAVE
variables is as follows :

   ;*************************************************************
   header = ' '
   data_points = 0
   Openr, 1, !!Data_Dir + 'bsc_data1.dat'
   Readf, 1, header           ;*** Read the header
   Readf, 1, data_points      ;*** Read the number of data points

   sc = 0.0
   t1 = 0
   t2 = 0.0
   cd = ''

   seconds = Fltarr(data_points)
   test1 = Intarr(data_points)
   test2 = Fltarr(data_points)
   code = Strarr(data_points)
   FOR i=0, (data_points-1) DO BEGIN      ;*** Read the data
      Readf, 1, sc, t1, t2, cd, Format='(F7.2, 1X, I5, F6.1, A5)'
      seconds(i) = sc 
      test1(i) = t1 
      test2(i) = t2 
      code(i) = cd
   ENDFOR
   Close, 1
   ;*************************************************************

A window in which to view the data can be created using the
PV-WAVE "Window" command :
 
   ;*************************************************************
   Window, 1, Xsize=512, Ysize=512, Title='Data Display Window'
   ;*************************************************************
 
Once a window has been created, the data can be viewed in many
different ways.   The following are a few PV-WAVE commands
that can display this data :

   ;*************************************************************
   Plot, seconds               ;(Plots the values in "seconds")
   Plot, seconds, test1        ;(Plots "test1" vs "seconds")
   Plot, seconds, test2        ;(Plots "test2" vs "seconds")
   Plot, test2, test1          ;(Plots "test1" vs "test2")
   Plot, test2, test1, Psym=2  ;(Scatter plot "test1" vs "test2")
   ;*************************************************************

The following set of PV-WAVE commands plots BOTH "test1"
and "test2" on the same graph :

   ;*************************************************************
   min_y = Min(test1) < Min(test2)
   max_y = Max(test1) > Max(test2)
   Plot, test1, Yrange=[min_y, max_y], Color=127
   Oplot, test2, Yrange=[min_y, max_y], Color=100
   ;*************************************************************

