How to Perform REPLACE for Two Databases w/ Common Field

MORE INFORMATION

1. Set the default directory to the location of CUSTOMER.DBF. For example, in FoxPro 2.x, issue the following command in the Command window:

         SET DEFAULT TO C:\<FoxPro_directory>\TUTORIAL.
   						

   In Visual FoxPro, Issue the following:

         SET DEFAULT TO C:\<FoxPro_directory>\SAMPLES\DATA
   						

   NOTE: In Visual FoxPro, you will also need to change all references below from from CNO to CUST_ID.
2. In the Command window, issue the following commands:

         USE customer
         COPY TO newcust
         SELECT 0
         USE newcust
         ** the following command has no spaces between the quotation marks
         REPLACE ALL company WITH ""
         ** BROWSE the table with the empty COMPANY field contents
         BROWSE
         CLEAR ALL
         CLOSE ALL
         ** open a new program file called TEST
         ** if a program called TEST already exists, choose another name
         MODIFY COMMAND test

3. In the edit window for the TEST program, type the following commands:

         SELECT 0
         USE customer
         SELECT 0
         USE newcust
   
         SELECT customer
   
         ** while not at end of file of CUSTOMER, do some actions
         DO WHILE !EOF()
            ** select the destination table
            SELECT newcust
            ** replace the empty COMPANY field with data from CUSTOMER where
            **   the common key field is the same
            REPLACE newcust.company WITH customer.company;
               FOR newcust.cno = customer.cno
            ** select the source table again to go to next record
            SELECT customer
            SKIP
         ENDDO
         SELECT newcust
         ** BROWSE the table with the newly filled COMPANY data
         BROWSE
   						

   NOTE: If the first database (that is, CUSTOMER) is indexed on the common key field between the two tables, replace the commands in step 3 with the following:

         SELECT 0
         USE customer ORDER TAG cno
         SELECT 0
         USE newcust
         REPLACE ALL newcust.company WITH customer.company FOR ;
            seek(cno,"customer")

4. Save TEST.PRG and then run it.