How to Populate an Array with a Discontiguous Range

MORE INFORMATION

Microsoft provides programming examples for illustration only, without warranty either expressed or implied. This includes, but is not limited to, the implied warranties of merchantability or fitness for a particular purpose. This article assumes that you are familiar with the programming language that is being demonstrated and with the tools that are used to create and to debug procedures. Microsoft support engineers can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific requirements. When the range is contiguous, there is no need to iterate through the range. The following Visual Basic macro code includes an example of how you can iterate through a discontiguous range of data to populate an array and an example of how you can use a contiguous range of data to populate an array.

To use the sample macro code, follow these steps:

1. Open a new workbook and insert a Visual Basic module sheet.
2. On the module sheet, type the following macro code:

          Sub PopulateArrayThroughIteration()
   
             ' Dimension the variables.
             Dim MyArray() As Integer
             Dim cell As Object
             Dim counter As Integer
   
             ' Set the value of the counter variable.
             counter = 1
   
             ' Start the loop on the range.
             For Each cell In Range("a1,a3:a20")
   
                 ' Redimension the array, while preserving the previous
                 ' elements using the counter variable.
                 ReDim Preserve MyArray(counter)
                 ' Place a value into the array.
                 MyArray(counter) = cell.Value
                 ' Increase counter by 1.
                 counter = counter + 1
             ' Loop.
             Next cell
   
             ' Check a value to make sure the array is populated
             ' this should return 5.
             MsgBox MyArray(4)
   
         End Sub
   						

3. On Sheet1, type the numbers 1 to 20 in the range A1:A20.
4. Activate Sheet1.
5. Run the macro. To do this, use the following steps:
   
   
   1. On the Tools menu, click Macro.
      
      -or-
      
      On the Tools menu, point to Macro, and then click Macros.
   2. In the Macro dialog box, select the name of the macro, and then click Run.

The following macro populates an array from a contiguous range of data.

   Sub PopulateArrayContiguous()
       Dim MyArray As Variant

       ' Populate the array.
       MyArray = Range("a1:a20")

       ' Display a message box with a value in the array
       ' this should display a 5.
       MsgBox MyArray(5, 1)

   End Sub