How to Create a List of Unique Random Integers Between Two Given Values

MORE INFORMATION

Microsoft provides programming examples for illustration only, without warranty either expressed or implied. This includes, but is not limited to, the implied warranties of merchantability or fitness for a particular purpose. This article assumes that you are familiar with the programming language that is being demonstrated and with the tools that are used to create and to debug procedures. Microsoft support engineers can help explain the functionality of a particular procedure, but they will not modify these examples to provide added functionality or construct procedures to meet your specific requirements. The following macro prompts the user for a starting integer and an ending integer, then the macro prompts the user to input the number of random numbers to generate. Next, it lists that number of unique integers on the active worksheet. To create and run the macro, follow these steps:

1. Type the following code in a module sheet:

         Option Explicit
   
         Sub Unique_Numbers()
   
            Dim x As Long, y As Long, z As Long, tempnum As Long
            Dim flag As Boolean
            Dim i As Integer
            Dim foundCell As Range
   
            Application.ScreenUpdating = False
   
            x = Application.InputBox("Enter starting Random Number" _
               , "Random Number Generation", 1, , , , , 1)
            y = Application.InputBox("Enter ending Random Number" _
               , "Random Number Generation", 1000, , , , , 1)
            z = Application.InputBox("How many random numbers would" _
               & "you like to generate (<15000)?" _
                   , "Random Number Generation", 100, , , , , 1)
            If z = 0 Then Exit Sub
   
            If z > 15000 Then z = 15000
   
            If z > y - x + 1 Then
                MsgBox "You specified more numbers to return than " _
                        & "are possible in the range!"
                Exit Sub
            End If
   
            Randomize
   
            Cells(1, 1) =  Int((y - x + 1) * Rnd + x)
   
            For i = 2 To z
                Do
                    flag = False
                    Randomize
                    tempnum = Int((y - x + 1) * Rnd + x)
   
                    Set foundCell = Range("a1", _
                           Range("a1").End(xlDown).Address).Find(tempnum)
                    If Not (foundCell Is Nothing) Then
                        flag = True
                    End If
   
                Loop Until Not flag
   
                Cells(i, 1) =  tempnum
   
            Next
   
         End Sub
   						

2. Open a blank worksheet.
3. On the Tools menu, click Macro.
   
   In Microsoft Excel 97, on the Tools menu, point to Macro, and click Macros.
4. Click the Unique_Numbers macro, and then click Run.