  DCL Task-to-Task? 
 The Question is:
 
I want to run remote-task on remote node over network.
On manual the following command is written :
$ type node"user password"::"task=command_procedure"
 
But, the command occurs error:
%TYPE-W-OPENIN,error opening node"user password"::"task=command_procedure" as input
-RMS-E-ACC, ACP file access failed
-SYSTEM-F-LINKEXIT, network parter exited
 
Let me know how to run remote task and how to setup environments.
 
 
 
 The Answer is :
 
  Check the NETSERVER.LOG on the remote system for clues to what
  happened when the remote end exited -- that there are problems
  in the DCL executing on the remote end is what the error you
  received means...
 
  The Ask The Wizard topics of interest here include (5409), (159)
  -- this topic, (798), (1910) and various others.
 
  Here is an example of an application that is both a DECnet
  client, and a server, based on F$Mode():
 
 
$!  XQTYPE.COM
$!
$   Set NoOn
$   Set NoVerif
$   vers = "0000|XQTYPE"
$   Goto 'F$Mode()'
$!
$!  Copyright 2002 Hewlett-Packard Company
$!  Copyright 1989 Digital Equipment Corporation
$!  Written: S Hoffman, 21-Jan-1989
$!
$!  Uses DCL DECnet task-to-task to check the device type of the XQA0:
$!  controller on the remote system.  Can return &lt;unknown&gt;, &lt;none&gt;,
$!  &lt;DELQA&gt; or &lt;DEQNA&gt;.  Requires VMS V5.0 or better as the procedure
$!  uses block-structured IF DCL syntax.
$!
$!  Calling:
$!	@XQTYPE node
$!
$!  Procedure must be named XQTYPE.COM and must reside in the default
$!  login directory on both the local and the remote nodes.  Note that
$!  the remote login may occur either in the directory specified by a
$!  proxy, if one exists, or in the DECNET directory.  If you're not
$!  sure the default directory can be found by entering the command
$!  "DIRECTORY node::".  Requires access to the DECNET TASK object on
$!  the remote end; either by the default DECNET username/password or
$!  via a proxy.
$!
$INTERACTIVE:
$DO_P1:
$   p1 = F$Edit(p1,"COLLAPSE,UPCASE") - "::"
$   If F$Leng(p1) .eq. 0
$   Then
$	msg = "Error reading input"
$	Read/Prompt="Node? "/Error=DONE Sys$Command p1
$	Goto DO_P1
$   EndIf
$!
$   msg = "Error creating network connection"
$   Open/Read/Write/Error=DONE net 'p1'::"task=XQTYPE"
$   Read net remvers
$   Write net vers
$   Read net XQType
$   Close net
$   Write Sys$Output "XQA0: Device type on node ''p1':: is ''XQType'"
$   msg = ""
$   Goto DONE
 
$NETWORK:
$   msg = "Error receiving network connection"
$   Open/Read/Write/Error=DONE net Sys$Net
$   Write net vers
$   Read net remvers
$   If F$GetDVI("XQA0:","EXISTS")
$   Then
$	DEVType = F$GetDVI("XQA0:","DEVTYPE")
$	XQType = "&lt;unknown&gt;"
$	If DEVType .eq. 33 Then XQType = "DELQA"
$	If DEVType .eq. 22 Then XQType = "DEQNA"
$   Else
$	XQType = "&lt;none&gt;"
$   EndIf
$   Write net XQType
$   Close net
 
$BATCH:
$OTHER:
$   msg = "Unsupported F$MODE()"
 
$DONE:
$   If F$Len(msg) .ne. 0 Then Write Sys$Output msg
$   Stop
$   Exit
 
 
 Answer written or last revised on  5-FEB-2003 
