$ if f$length(p1).le.0 then exit
$ newerfile = f$search(p1)
$ olderfile = f$search(p2)
$ outfile = p3
$ if newerfile.eqs.""
$ then
$    write sys$output "%CBAR-F-FILNOTFOU, File ''p2' not found."
$ else
$    if olderfile.eqs.""
$    then
$       write sys$output "%CBAR-F-FILNOTFOU, File ''p2' not found."
$    else
$       if outfile.eqs.""
$       then
$          write sys$output "%CBAR-F-BADFILE, Bad file name ''p3'."
$       else
$          diff/out=cbar_slp.tmp/slp 'olderfile' 'newerfile'
$          open/read old cbar_slp.tmp;
$          open/write new cbar_slp.tmp;
$          first = 1
$          loop:
$             read/end=end_loop old line
$             c1 = f$extract(0,1,line)
$             if c1.eqs."-".or.c1.eqs."/"
$             then 
$                if .not.first
$                then 
$                   write new ".eb"
$                endif
$                write new line
$                if c1.nes."/"
$                then
$                   write new ".bb"
$                   first = 0
$                endif
$             else
$                write new line
$             endif
$             goto loop
$          end_loop:
$          close old
$          close new
$          edit/sum/output='p3' 'olderfile'/update=cbar_slp.tmp
$          delete cbar_*.tmp;*
$          if first 
$          then 
$             write sys$output "%CBAR-W-NOCHGBARS, No change bars produced."
$             write sys$output "-CBAR-W-NODIFFS, No differences between files."
$          else
$             write sys$output "%CBAR-I-CHGBARS, Change bars produced."
$          endif
$       endif
$    endif
$ endif
$ exit