.TITLE	MOUNTF
;
;	SUBROUTINE MOUNTF(DEVICE,BLKSIZ,LRECL,DENSTY,VOLUME,  STATUS)
;
;	1982-SEP-08 -- JWB -- REVISION 0 -- VMS V3.0
;
;	ISSUE THE EQUIVALENT OF:
;	$MOUNT/FOREIGN/BLOCK=blksiz/RECORD=lrecl/DENSITY=densty -
;		device  volume
;
;	INPUTS:
;	  DEVICE - CHAR*6  - DEVICE NAME - E.G. '_MTA0:'
;	  BLKSIZ - INTEGER - BLOCKSIZE - E.G. 8192
;	  LRECL  - INTEGER - LOGICAL RECORD SIZE - E.G. 128
;	  DENSTY - INTEGER - TAPE DENSITY (BPI) - E.G. 1600
;	  VOLUME - CHAR*6  - VOLUME ID (STRAP LABEL) - E.G. 'V0023A'
;	OUTPUT:
;	  STATUS - INTEGER - SYSTEM STATUS CODE FROM $MOUNT
;
	$MNTDEF
UNUSED      = 0
END_OF_LIST = 0
DEVICE      = 4
BLKSIZ      = 8
LRECL       = 12
DENSTY      = 16
VOLUME      = 20
STATUS      = 24
;
	.PSECT	MOUNTFRD,RD,NOWRT,NOEXE,LONG
ITEMLIST:
	.WORD	6
	.WORD	MNT$_DEVNAM
	.ADDRESS     DEVNAM
	.LONG	UNUSED
;
	.WORD	6
	.WORD	MNT$_VOLNAM
	.ADDRESS     VOLNAM
	.LONG	UNUSED
;
	.WORD	4
	.WORD	MNT$_FLAGS
	.ADDRESS     FLAGS
	.LONG	UNUSED
;
	.WORD	4
	.WORD	MNT$_BLOCKSIZE
	.ADDRESS     BLOCKSIZE
	.LONG	UNUSED
;
	.WORD	4
	.WORD	MNT$_DENSITY
	.ADDRESS     DENSITY
	.LONG	UNUSED
;
	.WORD	4
	.WORD	MNT$_RECORDSIZ
	.ADDRESS     RECORDSIZE
	.LONG	UNUSED
;
	.WORD	COMMENT_LENGTH
	.WORD	MNT$_COMMENT
	.ADDRESS     COMMENT
	.LONG	UNUSED
;
	.LONG	END_OF_LIST
;
FLAGS:	.LONG	<MNT$M_FOREIGN!MNT$M_NOHDR3>
;
	.PSECT	MOUNTFRW,RD,WRT,NOEXE,LONG
BLOCKSIZE:	.BLKL
RECORDSIZE:	.BLKL
DENSITY:	.BLKL
DEVNAM:		.BLKB	6
VOLNAM:		.BLKB	6
COMMENT:	.ASCII	/MOUNTF-I-This request does not require a reply./
COMMENT_LENGTH	= .-COMMENT
;
	.PSECT	MOUNTFCD,EXE,NOWRT
	.ENTRY	MOUNTF,^M<R2,R3,R4,R5>	;MOVC3 CLOBBERS R0 THRU R5 !!!!
	MOVL	DEVICE(AP),R2		;ADDRESS OF DEVICE DESCRIPTOR
	MOVL	4(R2),R2		;ADDRESS OF DEVICE STRING
	MOVC3	#6,(R2),DEVNAM		;MOVE 6 CHARACTERS
	MOVL	@BLKSIZ(AP),BLOCKSIZE
	MOVL	@LRECL(AP),RECORDSIZE
	MOVL	@DENSTY(AP),DENSITY
	MOVL	VOLUME(AP),R2		;ADDRESS OF VOLUME DESCRIPTOR
	MOVL	4(R2),R2		;ADDRESS OF VOLUME STRING
	MOVC3	#6,(R2),VOLNAM
	$MOUNT_S ITMLST=ITEMLIST
	MOVL	R0,@STATUS(AP)		;RETURN SYSTEM STATUS CODE
	RET
	.END