SUBROUTINE INITDIFF
C Routine to inititalize the game difficulty variables to the values
C requested by the user
	IMPLICIT REAL*8 (A-Z)
	INCLUDE 'ARRAYS.INC/NOLIST'
C
	INTEGER*4 VALS(10,DIF_MAXLEVEL),I,INIT_SCORE
C Delta points for bonus life -----------------------+
C Barrier hit count - upper limit --------------+    |
C Barrier hit count - lower limit -----------+  |    |
C Target timer - upper limit -------------+  |  |    |
C Target timer - lower limit ---------+   |  |  |    |
C QUEUETARG targ idx - upper ------+  |   |  |  |    |
C QUEUETARG targ idx - lower ---+  |  |   |  |  |    |
C Millipede segment count ---+  |  |  |   |  |  |    |
C Active bullet limit ---+   |  |  |  |   |  |  |    |
C Trigger score -----+   |   |  |  |  |   |  |  |    |
C		     v   v   v  v  v  v   v  v  v    v
C
	DATA VALS /   0, 3, 15, 6, 7, 5, 15, 2, 5, 2000,
     1		   1000, 3, 16, 6, 7, 4, 14, 2, 5, 2000,
     2		   2000, 3, 16, 5, 8, 4, 10, 2, 5, 3000,
     3		   3000, 3, 17, 5, 8, 3,  9, 2, 6, 3000,
     4		   4000, 3, 18, 4, 8, 3,  9, 2, 6, 3500,
     5		   5000, 3, 19, 4, 8, 3,  8, 3, 6, 3500,
     6		   6000, 3, 19, 3, 9, 2,  7, 3, 6, 4000,
     7		   7000, 3, 20, 2,10, 2,  7, 3, 6, 4000,
     8		   8000, 3, 20, 2,10, 2,  6, 3, 6, 4000,
     9		  11000, 2, 20, 1,10, 2,  5, 4, 6, 5000,
     A	          90000, 0,  0, 0, 0, 0,  0, 0, 0,    0 /
C
C Move values from the above data statement into the difficulty
C arrays (see INCRDIFF for use of array)
C
	DO I = 1,DIF_MAXLEVEL
	  DIFV_SCORE(I)  = VALS(1,I)
	  DIFV_MAXBUL(I) = VALS(2,I)
	  DIFV_MAXSEG(I) = VALS(3,I)
	  DIFV_RL_TIX(I) = VALS(4,I)
	  DIFV_RU_TIX(I) = VALS(5,I)
	  DIFV_RL_TTM(I) = VALS(6,I)
	  DIFV_RU_TTM(I) = VALS(7,I)
	  DIFV_RL_BAR(I) = VALS(8,I)
	  DIFV_RU_BAR(I) = VALS(9,I)
	  DIFV_NULIFE(I) = VALS(10,I)
	ENDDO
C
C Set initial difficulty level as requested by player, and normalize
C trigger scores for higher difficulty levels
C
	DIF_LEVEL = DIF_INIT
	INIT_SCORE = DIFV_SCORE(DIF_INIT)
	DO I = DIF_INIT,DIF_MAXLEVEL-1
	  DIFV_SCORE(I) = DIFV_SCORE(I) - INIT_SCORE
	ENDDO
C
C Increment difficulty level so bonus life score comes out right,
C and set up so WRTSCR updates 'BONUS LIFE' value
C
	CALL INCRDIFF
	NEWLIFE(POINT_NEW) = 0
	NEWLIFE(POINT_OLD) = DIF_NULIFE
	RETURN
	END