$! *************************************************************************
$! *************************************************************************
$! **                                                                     **
$! **                                                                     **
$! **  The following command procedure or fortran program was written by: **
$! **                                                                     **
$! **  Aaron B. Stein                                                     **
$! **  USAE Waterways Experiment Station                                  **
$! **  Vicksburg, Mississippi, 39180                                      **
$! **                                                                     **
$! **  601-634-3283                                                       **
$! **                                                                     **
$! **                                                                     **
$! *************************************************************************
$! *************************************************************************
$! 
$	SET NOON
$!
$	SET VERIFY
$!
$	SET CONTROL=(Y,T)
$!
$!	MOUNT USER_DISK
$!
$	MOUNT/SYSTEM/PROCESSOR=UNIQUE  DRB0:  USER_DISK 
$!	LOGICAL NAMES
$!
$	ASSIGN/SYSTEM DISK$USER_DISK: USER_DISK:
$	ASSIGN/SYSTEM  SYS$MANAGER:SYLOGIN.COM SYS$SYLOGIN
$!
$!	SIGNON FLAG
$!
$	ASSIGN/SYSTEM    -
	"           WATER QUALITY MODELING GROUP   VAX 11/750 SYSTEM"-
	SYS$ANNOUNCE
$!
$!	SET UP PRINT QUEUE
$!
$	START/QUE/FLAG SYS$PRINT
$	IF $STATUS THEN GOTO LINEP
$	INI/QUE/GENERIC SYS$PRINT
$	START/QUEUE/FLAG SYS$PRINT
$LINEP:
$	SET DEVICE/SPOOLED=(LPA0,SYS$SYSDEVICE) LPA0:
$	START/QUEUE/FLAG LPA0:
$	IF $STATUS THEN GOTO RJE
$	INI QUEUE LPA0:
$	START/QUEUE/FLAG LPA0:
$!
$!	SET UP BATCH QUEUES
$!
$RJE:
$	@SYS$MANAGER:RJELOAD
$	START/QUE SF
$	IF $STATUS THEN GOTO BATCH
$	INIT/QUE/JOB_LIM=1/PRIOR=7/BATCH SF
$	START/QUE SF
$!
$!
$BATCH:
$	START/QUE SYS$BATCH
$	IF $STATUS THEN GOTO BLACK_HOLE
$	INITIALIZE/QUEUE/WSDEFAULT=450/WSQUOTA=600/WSEXTENT=2000	-
		/JOB_LIMIT=4/PRIORITY=2/BATCH SYS$BATCH
$	START/QUE SYS$BATCH
$!
$!
$BLACK_HOLE:
$	START/QUE BLACK_HOLE
$	IF $STATUS THEN GOTO TERMS
$	INITIALIZE/QUEUE/WSDEFAULT=450/WSQUOTA=600/WSEXTENT=2000	-
		/JOB_LIMIT=1/PRIORITY=1/BATCH BLACK_HOLE
$	START/QUE BLACK_HOLE
$!
$!
$!	SET UP TERMINALS
$!
$TERMS:
$	SET TERM/PERM/WIDTH=132 				OPA0:
$	SET TERM/PERM/VT100/SPEED=(9600,9600)/ADVANCED 		TTA0:
$	SET TERM/PERM/VT100/SPEED=(9600,9600)/ADVANCED 		TTA1:
$	SET TERM/PERM/VT100/SPEED=(9600,9600)/ADVANCED 		TTA2:
$	SET TERM/PERM/MODEM/HANG/AUTO/WIDTH=132/DEV=LA120	TTA3:
$	SET TERM/PERM/MODEM/HANG/AUTO/WIDTH=132/DEV=LA120	TTA4:
$	SET TERM/PERM/MODEM/HANG/AUTO/WIDTH=132/DEV=LA120	TTA5:
$	SET TERM/PERM/NOECHO/SPEED=(9600,9600)			TTA6:
$	SET TERM/PERM/WIDTH=132/SPEED=(9600,9600)-
		/NOBROADCAST/DEV=LA120			        TTA7:
$	SET TERM/PERM/VT52 /SPEED=(9600,9600)			TTB0:
$	SET TERM/PERM/VT100/SPEED=(9600,9600)/ADVANCED 		TTB1:
$	SET TERM/PERM/VT100/SPEED=(9600,9600)/ADVANCED 		TTB2:
$	SET TERM/PERM/SPEED=(2400,2400)				TTB3:
$	SET TERM/PERM/VT100/SPEED=(9600,9600)/ADVANCED		TTB4:
$	SET TERM/PERM/VT100/SPEED=(9600,9600)/ADVANCED 		TTB6:
$	SET TERM/PERM/VT100/SPEED=(9600,9600)/ADVANCED 		TTB7:
$!
$!	SET UP TERMINAL QUEUE FOR TTA7:
$!
$	SET DEVICE/SPOOLED=(TTA7,SYS$SYSDEVICE) TTA7:
$	START/QUEUE 				TTA7
$	IF $STATUS THEN GOTO END_TERMS
$	INITIALIZE/QUEUE/TERMINAL/NOENABLE	TTA7
$	START/QUEUE 				TTA7	
$END_TERMS:
$!
$!	INSTALL FORTRAN AS A SHARED IMAGE
$!
$FORTRAN:
$	RUN SYS$SYSTEM:INSTALL
	FORTRAN.EXE/OPEN/SHARED/HEADER_RESIDENT
$!
$!
$!	INSTALL SAS  AS A SHARED IMAGE
$!	AND DEFINE LOGICAL NAMES
$!
$SAS:
$	RUN SYS$SYSTEM:INSTALL
	XSAS.EXE/OPEN/SHARED/HEADER_RESIDENT
$!
$	ASSIGN/SYSTEM	MT:	 				SASTAPE
$	ASSIGN/SYSTEM	SYS$SYSROOT:[SYSMGR.SAS.MAPDATA]	SAS_MAP_DATA
$	ASSIGN/SYSTEM	SYS$SYSROOT:[SYSMGR.SAS.SAMPLES]	SAS_SAMPLES
$!
$!
$VERSATEC:
$!
$!	START VERSATEC
$!
$	@SYS$MANAGER:LVSTART
$	ASSIGN/SYSTEM LVA0: VEROUT 
$	SET DEVICE/SPOOLED=(LVA0,SYS$SYSDEVICE) LVA0:
$	START /QUEUE  LVA0:
$	IF $STATUS THEN GOTO VERSAEND
$	INITIALIZE/QUEUE /NOENABLE_GENERIC_PRINTING LVA0:
$	START /QUEUE  LVA0:
$!
$VERSAEND:
$!
$!	FINISH UP
$!
$EXIT:
$	SET NOVERIFY
$	SET ON
$	EXIT