ALWAYS	27JUL2	MAX	<DECLARE MAXIMUM TASK/SUBR CODE>
	.MCALL	DIR$,CALLR
	.PSECT
;************************************************************************
;*									*
;*	MODULE: MAX							*
;*									*
;*	FUNCTION: DECLARE MAXIMUM TASK/SUBR CODE			*
;*									*
;*	INPUT PARAMETERS:						*
;*									*
;*	R0 POINTS TO THE COMMAND LINE IN PROCESS			*
;*									*
;*	OUTPUT PARAMETERS:						*
;*									*
;*	R0 POINTS JUST BEYOND COMMAND LINE				*
;*									*
;*	DESTROYS:							*
;*									*
;*	AUTHOR: KEVIN ANGLEY						*
;*									*
;*	DATE: 27-JUL-82							*
;*									*
;************************************************************************

MAX::
	GETKEY	TASK		; TRY FOR KEYWORD "TASK"
	BNE	10$		;  NE: NOT "TASK"
	CALL	GETHX4		; GET 4-DIGIT HEX VALUE FOR MAXIMUM TASK CODE
	BCS	250$		;  CS: CONVERSION ERROR - TAKE ERROR EXIT
	MOV	R1,MAXTSK	; SET UP MAXIMUM TASK CODE
	BR	255$		; TAKE SUCCESS EXIT
10$:
	GETKEY	SUBR		; TRY FOR KEYWORD "SUBR"
	BNE	20$		;  NE: NOT "SUBR"
	CALL	GETHX4		; GET 4-DIGIT HEX VALUE FOR MAXIMUM SUBR CODE
	BCS	250$		;  CS: CONVERSION ERROR - TAKE ERROR EXIT
	BIS	#100000,R1	; FOR SUBROUTINE, SET HIGH BIT
	MOV	R1,MAXSUB	; SET UP MAXIMUM SUBR CODE
	BR	255$		; TAKE SUCCESS EXIT
20$:
	OUTPUT	MSK		; "MISSING KEYWORD"
				; FALL THRU TO ERROR EXIT
250$:				; ERRPR EXIT
255$:				; NORMAL EXIT
	CALLR	EXTRA		; PURGE COMMAND LINE OF SUPERFLUOUS JUNK
				;  AND RETURN FROM THERE

	.END