$!	name: resetpw.com
$!
$!	purpose: reset a forgotten password to the username
$!
$!	by: s. szep
$!
$!	date: 8/21/84
$!
$!	revised: 2/26/85
$!
$!	site: pratt institute
$!
$!	location: ac$mgr
$!
$!
$ 	on controly then goto cleanup
$ 	on warning then goto cleanup
$ 	set default sys$system
$!
$! get username for password-reset
$!
$ get_user:
$	inquire user_name "Account"
$	if user_name .eqs. "" -
		then goto get_user
$	if user_name .eqs. "DONE" -
		then goto cleanup
$!
$! check if this user has a VAX account?
$!
$ 	open/write file sys$login:lstuser.tmp
$ 	write file "assign/user nl: sys$output"
$ 	write file "run sys$system:authorize"
$ 	write file "list ''user_name' /full"
$ 	write file "exit"
$ 	close file
$!
$!
$! tuck away any old SYSUAF.LIS's into a safe place
$!
$ 	sfile = f$search("sysuaf.lis")
$ 	if sfile .eqs. "" -
		then goto no_old_list
$ 	rename sysuaf.lis;* sysuaf.sav;*
$ no_old_list:
$!
$! run the program LSTUSER.TMP
$!
$	@sys$login:lstuser.tmp
$	delete/nocon sys$login:lstuser.tmp;*/nolog
$!
$! check if we actually found this user's account
$!
$ 	sfile = f$search("sysuaf.lis")
$ 	if sfile .eqs. "" -
		then goto no_such_user
$ 	rename sysuaf.lis sysuaf.tmp
$!
$! check if we have any old SYSUAF.LIS's lying around
$!
$ 	sfile = f$search("sysuaf.sav")
$ 	if sfile .eqs. "" -
		then goto no_old_save
$ 	rename sysuaf.sav;* sysuaf.lis;*
$!
$ no_old_save:
$ 	sfile = f$search("sysuaf.tmp")
$ 	if sfile .eqs. "" -
		then goto no_such_user
$!
$!	Get user's ACCOUNT information
$!
$ 	open file sysuaf.tmp
$ find_acct:
$	read file line
$	pos = f$locate("Account",line)
$	if pos .eq. f$length(line) -
		then goto find_acct
$	acct = f$extract(12,2,line)
$!
$!	Now, set up original password
$!
$	if acct .eqs. "00" -
		then goto fac_pswd
$! student user
$	pswd = "STUDENT"
$	goto end_acct
$! faculty user
$	pswd = "FACULTY"
$	goto end_acct
$!
$ end_acct:
$	close file
$	delete/nocon sysuaf.tmp;*/nolog
$!
$! modify the password
$!
$ 	open/write file sys$login:moduaf.tmp
$ 	write file "run sys$system:authorize"
$ 	write file "mod ''user_name' /pass=''pswd'"
$ 	write file "exit"
$ 	close file
$!
$! run MODUAF.TMP
$!
$	@sys$login:moduaf.tmp
$	delete/nocon sys$login:moduaf.tmp;*/nolog
$!
$ 	write sys$output "*** ",user_name, -
		"'s password has been set to ", -
		user_name," ****"
$!
$! repeat for another user?
$!
$ 	goto get_user
$!
$! no account exists for the given username
$!  
$ no_such_user:
$ 	write sys$output "*** No account exists for the username ", -
		user_name," ***"
$ 	write sys$output "-Please try again..."
$	goto get_user
$!
$!  all done
$!
$ cleanup:
$ 	set default ac$mgr
$ 	exit