[INHERIT ('SYS$LIBRARY:STARLET.PEN')]
MODULE Fairchild_IO(OUTPUT);

{ Module containing procedures for READing and WRITEing Fairchild format object
  files. }

TYPE
	Fairchild_Record	= VARYING [511] OF CHAR;

VAR
	Object_File		: TEXT;

(******************** Declare External Variables and Constants ****************)

%INCLUDE 'HEX$DIRECTORY:HEXGLOB.INC/NOLIST'

(********************* External RTL Routine Declarations **********************)

%INCLUDE 'HEX$DIRECTORY:LIB.INC/NOLIST'
%INCLUDE 'HEX$DIRECTORY:STR.INC/NOLIST'

(******************* External Homemade Routine Declarations *******************)

[EXTERNAL] FUNCTION Hex_to_Dec(Hex_String: String_80): UNSIGNED; EXTERN;

[EXTERNAL] FUNCTION Get_File_Read(VAR File_Spec: String_80): BOOLEAN; EXTERN;

[EXTERNAL] FUNCTION Get_File_Write(VAR File_Spec: String_80): BOOLEAN; EXTERN;

[EXTERNAL] FUNCTION Do_Read_Compare(Byte: Unsigned_Byte; Location: UNSIGNED): BOOLEAN; EXTERN;

[EXTERNAL] PROCEDURE Init_High_Low; EXTERN;

[EXTERNAL] PROCEDURE Read_Stats; EXTERN;

[EXTERNAL] PROCEDURE Write_Stats; EXTERN;

[EXTERNAL] PROCEDURE Process_Command(Command_Line: String_80); EXTERN;

(**********************************************************************************************************************************)
(**********************************************************************************************************************************)
(**********************************************************************************************************************************)

FUNCTION Check_Checksum_Fairchild(String: Fairchild_Record): BOOLEAN;

{ This function returns TRUE if the checksum field of the passed Fairchild format object file record is correct and FALSE
  otherwise. }

VAR
	I		: INTEGER;
	Sum		: UNSIGNED;

BEGIN

  Sum := 0;
  FOR I := 2 TO String.LENGTH - 1 DO
    Sum := Sum + Hex_to_Dec(SUBSTR(String,I,1));
  IF (Sum MOD 16 = Hex_to_Dec(SUBSTR(String,String.LENGTH,1))) THEN
    Check_Checksum_Fairchild := TRUE
  ELSE
    Check_Checksum_Fairchild  := FALSE;

END;

(**********************************************************************************************************************************)

[GLOBAL] PROCEDURE Read_Fairchild;

{ This procedure reads a Fairchild format object file into virtual memory. }

VAR
       	Object_File_Spec	: String_80;
	Error	       		: BOOLEAN;
	Done			: BOOLEAN;
	File_Record		: Fairchild_Record;
	Bytes_in_Record		: UNSIGNED;
	Load_Address		: UNSIGNED;
	N			: UNSIGNED;
	Data_Byte		: Unsigned_Byte;

BEGIN

  Error :=  NOT Get_File_Read(Object_File_Spec);	(* is the object file there? *)

  IF (NOT Error) THEN	(* open and reset the file *)
    BEGIN
      OPEN(Object_File,Object_File_Spec,READONLY,ERROR := CONTINUE);
      IF (STATUS(Object_File) <> 0) THEN
	BEGIN                                         
	  LIB$SIGNAL(hex_openerr,1,%STDESCR SUBSTR(Object_File_Spec,1,Object_File_Spec.LENGTH));
	  Error := TRUE;
	END
      ELSE
        RESET(Object_File);
    END;

  IF (NOT Error) THEN
    BEGIN
      Done := FALSE;
      Init_High_Low;
      WHILE(NOT EOF(Object_File) AND (NOT Error) AND (NOT Done)) DO
	BEGIN
	  READLN(Object_File,File_Record);
	  STR$TRIM(File_Record,File_Record);

	  IF ((File_Record.LENGTH > 0) AND (File_Record[1] = '*')) THEN Done := TRUE;

	  IF ((NOT Done) AND (File_Record.LENGTH > 0) AND ((File_Record[1] <> 'S') AND (File_Record[1] <> 'X'))) THEN
	    BEGIN
	      LIB$SIGNAL(hex_formaterr,1,%STDESCR 'Fairchild');
	      Error := TRUE;
	    END;

	  IF ((File_Record.LENGTH > 0) AND (NOT Error) AND (NOT Done) AND
	      (File_Record[1] = 'X') AND (ODD(File_Record.LENGTH))) THEN
	    BEGIN
	      LIB$SIGNAL(hex_formaterr,1,%STDESCR 'Fairchild');			(* uneven number of hex digits - *)
	      Error := TRUE;							(* for data record.		 *)
	    END;

	  IF ((File_Record.LENGTH > 0) AND (NOT Error) AND (NOT Done) AND
	      (File_Record[1] = 'S') AND (NOT ODD(File_Record.LENGTH))) THEN
	    BEGIN
	      LIB$SIGNAL(hex_formaterr,1,%STDESCR 'Fairchild');			(* uneven number of hex digits - *)
	      Error := TRUE;							(* for load address record.	 *)
	    END;

	  IF ((NOT Error) AND (NOT Done) AND						(* non-hexadecimal characters in *)
	      (File_Record.LENGTH > 0) AND						(* record.			 *)
	      (STR$FIND_FIRST_NOT_IN_SET(SUBSTR(File_Record,2,File_Record.LENGTH - 1),'0123456789ABCDEF') <> 0)) THEN
	    BEGIN
	      LIB$SIGNAL(hex_readnonhex);
	      Error := TRUE;
	    END;

	  IF ((NOT Error) AND (File_Record.LENGTH > 0) AND (NOT Done) AND (File_Record[1] = 'S')) THEN
	    Load_Address := Hex_to_Dec(SUBSTR(File_Record,2,4));

	  IF ((NOT Error) AND (File_Record.LENGTH > 0) AND (NOT Done) AND (File_Record[1] = 'X')) THEN
	    BEGIN
 	      Error := NOT Check_Checksum_Fairchild(File_Record);
	      IF (Error) THEN LIB$SIGNAL(hex_readsumerr,1,%STDESCR SUBSTR(File_Record,1,File_Record.LENGTH));
	    END;
	  
	  IF ((NOT Error) AND (File_Record.LENGTH > 0) AND (NOT Done) AND (File_Record[1] = 'X')) THEN
	    BEGIN
	      Bytes_in_Record := (File_Record.LENGTH - 2) DIV 2;
	      N := Use_1;
	      WHILE (N <= Bytes_in_Record) DO
		BEGIN
		  Data_Byte := ORD(Hex_to_Dec(SUBSTR(File_Record,2+2*(N-1),2)));
		  N := N + Use_2;
		  IF (((Load_Address >= From) AND (Load_Address <= Thru)) OR (NOT Range_Specified)) THEN
		    BEGIN
		      Error := NOT Do_Read_Compare(Data_Byte,Load_Address);
		      IF (NOT Error) THEN Byte_Count := Byte_Count + 1;
		      Load_Address := Load_Address + Step_Param;
		    END
	      	  ELSE Load_Address := Load_Address + 1;
		END;
	    END;

	END;
      CLOSE(Object_File);

      IF ((NOT Error) AND (NOT Done) AND (NOT Partial)) THEN			(* was there a trailer record? *)
	LIB$SIGNAL(hex_notrailer);
      IF (Byte_Count > 0) THEN Read_Stats;

    END;

END;

(**********************************************************************************************************************************)

FUNCTION Add_Checksum_Fairchild(String: Fairchild_Record): Fairchild_Record;

{ This function appends the checksum digit to an otherwise complete Fairchild format object file record. }

VAR
	Sum		: UNSIGNED;
	I		: INTEGER;

BEGIN

  Sum := 0;
  FOR I := 2 TO String.LENGTH DO
    Sum := Sum + Hex_to_Dec(SUBSTR(String,I,1));
  Add_Checksum_Fairchild := String + HEX(Sum MOD 16,1);

END;

(**********************************************************************************************************************************)

PROCEDURE Write_to_File_Fairchild;

{ This procedure writes the desigated range of virtual memory to the file variable Object_File }

VAR
	Object_Record		: Fairchild_Record;
	I			: UNSIGNED;
	J			: INTEGER;
	Load_Addr		: UNSIGNED;

BEGIN

  Object_Record := 'S' + HEX(From,4);		(* write out load address records *)
  WRITELN(Object_File,Object_Record);

  I := From;
  Byte_Count := 0;
  WHILE (I <= Thru) DO				(* write out data records *)
    BEGIN
      IF (Plus_Minus_Flag = Plus) THEN
	Load_Addr := I + Plus_Minus_Value
      ELSE
	Load_Addr := I - Plus_Minus_Value;
      Object_Record := 'X';
      J := 0;
      WHILE ((J < Width) AND (I <= Thru)) DO	(* add up to Width bytes to a record *)
	BEGIN
	  J := J + 1;
	  Object_Record := Object_Record + HEX(VM[(I-Offset)::INTEGER],2);
	  I := I + Step_Param;
	  Byte_Count := Byte_Count + 1;
	END;
      Object_Record := Add_Checksum_Fairchild(Object_Record);
      WRITELN(Object_File,Object_Record);
    END;

  IF (NOT Partial) THEN WRITELN(Object_File,'*');

  CLOSE(Object_File);

  Write_Stats;

END;

(**********************************************************************************************************************************)

[GLOBAL] PROCEDURE Write_Fairchild;

{ This procedure writes the specified range of virtual memory into a Fairchild format object file. }

VAR
	Sys_Stat		: INTEGER;
      	File_Spec		: String_80;

BEGIN

  IF (Get_File_Write(Output_File)) THEN
    BEGIN
      File_Spec := SUBSTR(Output_File,1,INDEX(Output_File,';')-1);	(* strip off the virgin number *)
      OPEN(Object_File, File_Spec, HISTORY := NEW);
      REWRITE(Object_File);
      Write_to_File_Fairchild;
    END;

END;

(**********************************************************************************************************************************)

[GLOBAL] PROCEDURE Append_Fairchild;

{ This procedure appends the given range of virtual memory to the specified file. }

VAR
       	Object_File_Spec	: String_80;
	Error	       		: BOOLEAN;
	Obj_Record		: Fairchild_Record;

BEGIN

  Error := FALSE;
  Error :=  NOT Get_File_Read(Object_File_Spec);	(* is the object file there? *)

  IF (NOT Error) THEN	(* open and reset the file *)
    BEGIN
      OPEN(Object_File,Object_File_Spec,OLD,ERROR := CONTINUE);
      IF (STATUS(Object_File) <> 0) THEN
	BEGIN
	  LIB$SIGNAL(hex_openerr,1,%STDESCR SUBSTR(Object_File_Spec,1,Object_File_Spec.LENGTH));
	  Error := TRUE;
	END
      ELSE
        RESET(Object_File);
    END;

  IF (NOT Error) THEN
    BEGIN
      WHILE (NOT EOF(Object_File)) DO READLN(Object_File,Obj_Record);
      TRUNCATE(Object_File);
      Write_to_File_Fairchild;
    END;

END;

(**********************************************************************************************************************************)

END. { module fairchild_io }