[INHERIT ('SYS$LIBRARY:STARLET.PEN')]
MODULE Tekhex_IO(OUTPUT);

{ Module containing procedures for READing and WRITEing Tekhex format object
  files. }

TYPE
	Tekhex_Record		= VARYING [511] OF CHAR;

VAR
	Object_File		: TEXT;

(******************** Declare External Variables and Constants ****************)

%INCLUDE 'HEX$DIRECTORY:HEXGLOB.INC/NOLIST'

(********************* External RTL Routine Declarations **********************)

%INCLUDE 'HEX$DIRECTORY:LIB.INC/NOLIST'
%INCLUDE 'HEX$DIRECTORY:STR.INC/NOLIST'

(******************* External Homemade Routine Declarations *******************)

[EXTERNAL] FUNCTION Hex_to_Dec(Hex_String: String_80): UNSIGNED; EXTERN;

[EXTERNAL] FUNCTION Get_File_Read(VAR File_Spec: String_80): BOOLEAN; EXTERN;

[EXTERNAL] FUNCTION Get_File_Write(VAR File_Spec: String_80): BOOLEAN; EXTERN;

[EXTERNAL] PROCEDURE Init_High_Low; EXTERN;

[EXTERNAL] FUNCTION Do_Read_Compare(Byte: Unsigned_Byte; Location: UNSIGNED): BOOLEAN; EXTERN;

[EXTERNAL] PROCEDURE Read_Stats; EXTERN;

[EXTERNAL] PROCEDURE Write_Stats; EXTERN;

[EXTERNAL] PROCEDURE Process_Command(Command_Line: String_80); EXTERN;

(**********************************************************************************************************************************)
(**********************************************************************************************************************************)
(**********************************************************************************************************************************)

FUNCTION Tekhex_Check_Checksum(String: Tekhex_Record): BOOLEAN;

{ This function returns TRUE if the checksums included in the Tekhex format object record and FALSE otherwise. }

VAR
	Sum		: UNSIGNED;
	I		: INTEGER;
	Checksum	: UNSIGNED;

BEGIN

  Sum := 0;
  FOR I := 2 TO 7 DO					{ check the first checksum }
    Sum := Sum + Hex_to_Dec(SUBSTR(String,I,1));
  Checksum := Hex_to_Dec(SUBSTR(String,8,2));
  IF (Sum <> Checksum) THEN
    Tekhex_Check_Checksum := FALSE
  ELSE
    BEGIN						{ check the second checksum }
      Sum := 0;
      FOR I := 10 TO String.LENGTH - 2 DO
	Sum := Sum + Hex_to_Dec(Substr(String,I,1));
      Checksum := Hex_to_Dec(Substr(String,String.LENGTH-1,2));
      IF (Sum MOD 256 = Checksum) THEN
	Tekhex_Check_Checksum := TRUE
      ELSE
	Tekhex_Check_Checksum := FALSE;
    END;

END;

(**********************************************************************************************************************************)

[GLOBAL] PROCEDURE Read_Tekhex;

{ This procedure reads in Tekhex format object file into virtual memory. }

VAR
       	Object_File_Spec	: String_80;
	Error	       		: BOOLEAN;
	Transfer_Set		: BOOLEAN;
	Name_Specified		: BOOLEAN;
	Done	     		: BOOLEAN;
	File_Record		: Tekhex_Record;
	Bytes_in_Record		: UNSIGNED;
	Load_Address		: UNSIGNED;
	Data_Byte		: Unsigned_Byte;
	N			: INTEGER;

BEGIN

  Transfer_Set := FALSE;
  Name_Specified := FALSE;

  Error :=  NOT Get_File_Read(Object_File_Spec);	(* is the object file there? *)

  IF (NOT Error) THEN	(* open and reset the file *)
    BEGIN
      OPEN(Object_File,Object_File_Spec,OLD,ERROR := CONTINUE);
      IF (STATUS(Object_File) <> 0) THEN
	BEGIN
	  LIB$SIGNAL(hex_openerr,1,%STDESCR SUBSTR(Object_File_Spec,1,Object_File_Spec.LENGTH));
	  Error := TRUE;
	END
      ELSE
        RESET(Object_File);
    END;

  IF (NOT Error) THEN
    BEGIN
      Done := FALSE;
      Init_High_Low;
      WHILE(NOT EOF(Object_File) AND (NOT Error) AND (NOT Done)) DO
	BEGIN
	  READLN(Object_File,File_Record);
	  STR$TRIM(File_Record,File_Record);
	  IF ((File_Record.LENGTH > 0) AND (File_Record[1] <> '/')) THEN		(* no % - illegal format *)
	    BEGIN
	      LIB$SIGNAL(hex_formaterr,1,%STDESCR 'TEKHEX');
	      Error := TRUE;
	    END;

	  IF (NOT Error) AND (NOT ODD(File_Record.LENGTH)) THEN				(* uneven number of hex digits - *)
	    BEGIN									(* illegal format		 *)
	      LIB$SIGNAL(hex_formaterr,1,%STDESCR 'TEKHEX');
	      Error := TRUE;
	    END;

	  IF ((NOT Error) AND (File_Record.LENGTH > 0) AND (File_Record.LENGTH < 9)) THEN
	    BEGIN
	      LIB$SIGNAL(hex_formaterr,1,%STDESCR 'TEKHEX');
	      Error := TRUE;
	    END;

	  IF ((NOT Error) AND								(* non-hexadecimal characters in *)
	      (File_Record.LENGTH > 0) AND						(* record.			 *)
	      (STR$FIND_FIRST_NOT_IN_SET(SUBSTR(File_Record,2,File_Record.LENGTH - 1),'0123456789ABCDEF') <> 0)) THEN
	    BEGIN
	      LIB$SIGNAL(hex_readnonhex);
	      Error := TRUE;
	    END;

	  IF ((NOT Error) AND (File_Record.LENGTH > 0)) THEN				(* what about the checksum? *)
	    BEGIN
	      Error := NOT Tekhex_Check_Checksum(File_Record);
	      IF (Error) THEN LIB$SIGNAL(hex_readsumerr,1,%STDESCR SUBSTR(File_Record,1,File_Record.LENGTH));
	    END;

	  IF (NOT Error) THEN
	    BEGIN
	      Bytes_in_Record := Hex_to_Dec(SUBSTR(File_Record,6,2));
	      IF (Bytes_in_Record = 0) THEN
		BEGIN
	          Done := TRUE;
		  IF (Partial) THEN LIB$SIGNAL(hex_unexptrailer);
		END
	      ELSE
		BEGIN
		  IF (2 * Bytes_in_Record + 11 <> File_Record.LENGTH) THEN
		    BEGIN
		      LIB$SIGNAL(hex_recformaterr,1,%STDESCR SUBSTR(File_Record,1,File_Record.LENGTH));
		      Error := TRUE;
		    END;
		END;
	    END;

	  IF ((NOT Error) AND (File_Record.LENGTH > 0)) THEN		(* Get load address and process record *)
	    BEGIN
	      Load_Address := Hex_to_Dec(SUBSTR(File_Record,2,4));
	      IF (Bytes_in_Record > 0) THEN						(* Data record *)
		BEGIN
		  N := Use_1;
		  WHILE (N <= Bytes_in_Record) DO
		    BEGIN
		      Data_Byte := ORD(Hex_to_Dec(SUBSTR(File_Record,10+2*(N-1),2)));
		      N := N + Use_2;
		      IF (((Load_Address >= From) AND (Load_Address <= Thru)) OR (NOT Range_Specified)) THEN
			BEGIN
		      	  Error := NOT Do_Read_Compare(Data_Byte,Load_Address);
		       	  IF (NOT Error) THEN Byte_Count := Byte_Count + 1;
			  Load_Address := Load_Address + Step_Param;
			END
	      	      ELSE Load_Address := Load_Address + 1;
		    END;
		END;
	    END;

	END;

      CLOSE(Object_File);
      IF ((NOT Error) AND (NOT Done) AND (NOT Partial)) THEN			(* was there a trailer record? *)
	LIB$SIGNAL(hex_notrailer);
      IF (Name_Specified) THEN Process_Command('NAME');
      IF (Byte_Count > 0) THEN Read_Stats;
      IF (Transfer_Set) THEN Process_Command('TRANSFER');
    END;

END;

(**********************************************************************************************************************************)

FUNCTION Add_Checksum_Tekhex(String: Tekhex_Record): Tekhex_Record;

{ This function adds the checksums to a Tekhex Data Record }

VAR
	Sum			: UNSIGNED;
	I			: INTEGER;

BEGIN

  Sum := 0;
  FOR I := 2 TO 6 DO
    Sum := Sum + Hex_to_Dec(SUBSTR(String,I,1));
  String := SUBSTR(String,1,7) + HEX(Sum,2) + SUBSTR(String,10,String.LENGTH - 9);
  Sum := 0;
  FOR I := 10 TO String.LENGTH DO
    Sum := Sum + Hex_to_Dec(SUBSTR(String,I,1));
  Add_Checksum_Tekhex := String + HEX(Sum MOD 256,2);

END;

(**********************************************************************************************************************************)

PROCEDURE Write_to_File_Tekhex;

{ This procedure writes the desigated range of virtual memory to the file variable Object_File }

VAR
	Object_Record		: Tekhex_Record;
	I			: UNSIGNED;
	J			: INTEGER;
	Load_Addr		: UNSIGNED;
	Sum			: UNSIGNED;

BEGIN

  I := From;
  Byte_Count := 0;
  WHILE (I <= Thru) DO				(* write out data records *)
    BEGIN
      IF (Plus_Minus_Flag = Plus) THEN
	Load_Addr := I + Plus_Minus_Value
      ELSE
	Load_Addr := I - Plus_Minus_Value;
      Object_Record := '00';
      J := 0;
      WHILE ((J < Width) AND (I <= Thru)) DO	(* add up to Width bytes to a record *)
	BEGIN
	  J := J + 1;
	  Object_Record := Object_Record + HEX(VM[(I-Offset)::INTEGER],2);
	  I := I + Step_Param;
	  Byte_Count := Byte_Count + 1;
	END;
      Object_Record := '/' + HEX(Load_Addr,4) + HEX(J,2) + Object_Record;	(* add the bytes in the record to the record *)
      Object_Record := Add_Checksum_Tekhex(Object_Record);		(* add the checksum to the record *)
      WRITELN(Object_File,Object_Record);
    END;

  IF (NOT Partial) THEN				(* tack on an end of file record *)
    BEGIN
      Object_Record := '/' + HEX(Transfer,4) + '00';
      Sum := 0;
      FOR I := 2 TO 6 DO
	Sum := Sum + Hex_to_Dec(SUBSTR(Object_Record,I,1));
      Object_Record := Object_Record + HEX(Sum,2);
      WRITELN(Object_File,Object_Record);
    END;

  CLOSE(Object_File);

  Write_Stats;

END;

(**********************************************************************************************************************************)

[GLOBAL] PROCEDURE Write_Tekhex;

{ This procedure writes the specified range of virtual memory into a Tekhex format object file. }

VAR
	Sys_Stat		: INTEGER;
      	File_Spec		: String_80;

BEGIN

  IF (Get_File_Write(Output_File)) THEN
    BEGIN
      File_Spec := SUBSTR(Output_File,1,INDEX(Output_File,';')-1);	(* strip off the virgin number *)
      OPEN(Object_File, File_Spec, HISTORY := NEW);
      REWRITE(Object_File);
      Write_to_File_Tekhex;
    END;

END;

(**********************************************************************************************************************************)

[GLOBAL] PROCEDURE Append_Tekhex;

{ This procedure appends the given range of virtual memory to the specified file. }

VAR
       	Object_File_Spec	: String_80;
	Error	       		: BOOLEAN;
	Obj_Record		: Tekhex_Record;

BEGIN

  Error := FALSE;
  Error :=  NOT Get_File_Read(Object_File_Spec);	(* is the object file there? *)

  IF (NOT Error) THEN	(* open and reset the file *)
    BEGIN
      OPEN(Object_File,Object_File_Spec,OLD,ERROR := CONTINUE);
      IF (STATUS(Object_File) <> 0) THEN
	BEGIN
	  LIB$SIGNAL(hex_openerr,1,%STDESCR SUBSTR(Object_File_Spec,1,Object_File_Spec.LENGTH));
	  Error := TRUE;
	END
      ELSE
        RESET(Object_File);
    END;

  IF (NOT Error) THEN
    BEGIN
      WHILE (NOT EOF(Object_File)) DO READLN(Object_File,Obj_Record);
      TRUNCATE(Object_File);
      Write_to_File_Tekhex;
    END;

END;

(**********************************************************************************************************************************)

END. { module tekhex_io }