$	set noon
$	verify= f$verify( 0 )
$	on control_y then goto exit_tree
$!
$! TREE
$! Version 1.1
$!
$! Purpose:
$!
$!	Produce an indented list of the directory structure below the
$!	current directory.
$!
$!	Example:	TREE
$!
$! Author(s):  James J. Fullerton
$! Creation Date:  14-APR-1989
$! Date Last Approved:  14-JUN-1989
$! Revisions (Date, Name, and summary of revision(s)):
$!
$	depth= 1
$	indent= "    "
$	level'depth'= f$directory() - "[" - "]"
$	write sys$output level'depth'
$!
$! Traverse directory substructure.
$!
$ next_in_tree:
$!
$	level= level'depth'
$	node= f$search( "[''level']*.DIR", 'depth' )
$	if node .eqs. ""
$	then
$		if depth .eq. 1
$		then
$			goto exit_tree
$		else
$			depth= depth - 1
$			indent= indent - "    "
$			goto next_in_tree
$		endif
$	else
$!		!!
$!		!! Display node name.
$!		!!
$		node_name= f$parse( node,,, "NAME" )
$		write sys$output indent+node_name
$!		!!
$!		!! Traverse that node.
$!		!!
$		depth= depth + 1
$		indent= indent + "    "
$		level'depth'= level + "." + node_name
$		goto next_in_tree
$	endif
$!
$ exit_tree:
$!
$	verify= f$verify( verify )
$	exit