echo off
cls
echo		* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
echo		*								*
echo		*	This batch file copies the Pocket adapter driver for	*
echo		*	NOVELL NetWare to the directory  LAN_DRV_.410  on the	*
echo		*	harddisk or network drive where you generate the shell.	*
echo		*								*
echo		*	Before invoking this batch file, the environment	*
echo		*	needed for the generation must be ready:		*
echo		*	The NOVELL directories and files needed must be in	*
echo		*	place.							*
echo		*								*
echo		* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
echo ÿ
if "%1"=="" goto help
if exist %1\system-1\nlink.exe goto chkfloppy
if exist %1\system-2\nlink.exe goto chkfloppy
if exist %1\wsgen\nlink.exe    goto chkfloppy
if exist %1\routegen\nlink.exe goto chkfloppy
if exist %1\auxgen\nlink.exe   goto chkfloppy
if not exist %1\shgen-1\nlink.exe goto baddir
:chkfloppy
if not exist \soc02n16.lan  goto badfloppy
if not exist \soc02n16.obj goto badfloppy
if not exist \soclsup.lan  goto badfloppy
if not exist \soclsup.obj  goto badfloppy
if not exist %1\lan_drv_.410 goto dirok
del %1\lan_drv_.410 > nul
:dirok
md %1\lan_drv_.410 > nul
copy \soc02n16.lan  %1\lan_drv_.410 > nul
copy \soc02n16.obj %1\lan_drv_.410 > nul
copy \soclsup.lan  %1\lan_drv_.410 > nul
copy \soclsup.obj  %1\lan_drv_.410 > nul
if not exist %1\auxgen\nlink.exe goto copyok
copy \soc02n16.lan %1\auxgen > nul
:copyok
if not exist %1\auxgen\nlink.exe goto noaux
echo		Files have been copied to directories
echo		%1\LAN_DRV_.410  and
echo		%1\AUXGEN
goto showlast
:noaux
echo		Files have been copied to the directory
echo		%1\LAN_DRV_.410
:showlast
echo		When running one of the generation programs, the pocket 
echo		adapter driver should appear in the list of available
echo		LAN drivers.
goto done

:badfloppy
echo		Unable to read file(s) from diskette.
echo		Make sure the diskette in the current drive contains
echo		the NOVELL network drivers for the Pocket Adapters.
goto done

:baddir
echo		The path specified must designate the work directory on the
echo		harddisk or network drive containing the directories needed
echo		for the generation (WSGEN etc).
echo		The drive letter and the full path is required.
goto done

:help
echo		Usage:		NOVLINST targetpath
echo		'targetpath' defines the drive and work directory containing
echo		the directories needed for the generation (such as WSGEN etc).
echo		The drive and full path must be specified.
echo		Example:	NOVLINST C:\GENERATE\NETWARE
:done
echo ÿ